KM OOCC índice de nombres

From Inguma Wikibase

Euskarazko bertsioa ikusi

Descripción de los experimentos

  • Artículo en castellano en preparación, describiendo los siguientes experimentos:
    • Experimentos con los artículos de las revistas ASJU y UZTARO (citaciones de la obra de Mitxelena): Véase la página Ziterauzi_KM (en euskera)
    • Experimentos para estructurar y enriquecer los índices de nombres en OOCC (véanse los resultados a continuación)

Entidades en OOCC

Las Obras Completas (OOCC) de Mitxelena (2011) contienen en su volumen XV un índice de nombres, que fue producido a mano por los editores, siguiendo el siguiente método: A los índices en Fonética Histórica Vasca se les añadieron las menciones de nombres propios en los demás textos incluidos en OOCC. Hemos recogido los nombres del listado, junto a las referencias a sus menciones en los textos, en esta instancia de Wikibase. A continuación, intentamos añadir a cada mención por una parte el contexto original, y por otra, hemos intentado identificar a la entidad mencionada con su identificador en Wikidata. Entendemos este experimento como contribución a mejorar la accesibilidad de la obra de Mitxelena.

Entidades mencionadas en OOCC en su contexto 1

Las menciones de las entidades aparecen juntas (una línea de tabla por entidad) 

#title: concepts part of "OOCC índice de nombres", and their occurrences in OOCC
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?entity ?oocc_label ?wikidata (count(distinct ?aipu) as ?zenbat_aipu) (group_concat (distinct ?text; SEPARATOR = "|") as ?contexts)
where {
  ?entity idp:P32 iwb:Q45164; rdfs:label ?oocc_label. filter(lang(?oocc_label)="eu")
  ?entity ip:P92 ?aipu. optional {?aipu ipq:P93 ?text.}
  optional {?entity idp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)}
  
 } group by ?entity ?oocc_label ?wikidata ?zenbat_aipu ?contexts order by desc(?zenbat_aipu)

Try it!


Entidades mencionadas en OOCC en su contexto 2

Las menciones de las entidades aparecen separadas, cada una en una línea de tabla. 

#title: concepts part of "OOCC índice de nombres" and their occurrences-in-context in OOCC
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select distinct ?entity ?oocc_label ?wikidata ?testua ?testu_izena ?aipua
where {
  ?entity idp:P32 iwb:Q45164; rdfs:label ?oocc_label. filter(lang(?oocc_label)="eu")
  ?entity ip:P92 ?aipu_st. ?aipu_st ips:P92 ?testua. 
  ?testua rdfs:label ?testu_izena. filter(lang(?testu_izena)="eu")
  optional {?aipu_st ipq:P93 ?aipua.} 
  
  optional {?entity idp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)}
  
 } group by ?entity ?oocc_label ?wikidata ?testua ?testu_izena ?aipua order by ?oocc_label ?testua ?aipua

Try it!


Entidades mencionadas en OOCC (gráfico de barras)

Este grafo muestra las identidades con 20 o más menciones en OOCC. 

#defaultView:BarChart
#title: concepts part of "OOCC índice de nombres", and their occurrences in OOCC
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?entity ?oocc_label ?wikidata ?zenbat_aipu where 
{ filter(?zenbat_aipu >= 20)
 { select ?entity ?oocc_label ?wikidata (count(distinct ?aipu) as ?zenbat_aipu) where 
  { ?entity idp:P32 iwb:Q45164; rdfs:label ?oocc_label. filter(lang(?oocc_label)="eu")
    ?entity ip:P92 ?aipu.
    optional { ?entity idp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata) } 
  } group by ?entity ?oocc_label ?wikidata ?zenbat_aipu 
 } 
} order by desc(?zenbat_aipu)

Try it!

Entidades mencionadas en OOCC (visualicación de tipo grafo)

Para delimitar el conjunto de datos, este grafo sólo muestra entidades identificadas en Wikidata. 

#defaultView:Graph
#title: entities part of "OOCC índice de nombres" and the OOCC parts they are referenced in
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select distinct ?entity ?entityLabel ?testua ?testuaLabel ?rgb
where {
  ?entity idp:P32 iwb:Q45164; idp:P1 ?wd; rdfs:label ?entitylabel. filter(lang(?entitylabel)="eu")
  bind(replace(str(?entitylabel),"\\.[^\\.]*", "") as ?entityLabel) 
  ?entity idp:P92 ?testua. 
  ?testua rdfs:label ?testuaLabel. filter(lang(?testuaLabel)="eu")
  bind ("FFFF99" as ?rgb)
 }

Try it!


Entidades mencionadas en el índice de OOCC que no han podido ser encontrados en contexto

Para las entidades mencionadas en este listado no hemos podido encontrar el contexto original. 

#title: concepts part of "OOCC índice de nombres" with no found context
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select distinct ?entity ?oocc_label ?wikidata
where {
  ?entity idp:P32 iwb:Q45164; rdfs:label ?oocc_label. filter(lang(?oocc_label)="eu")
  filter not exists {?entity ip:P92 ?aipu. ?aipu ipq:P93 ?text. }
  optional {?entity idp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)}
  
 } group by ?entity ?oocc_label ?wikidata ?aipu

Try it!

Para las entidades de este listado, no hemos podido encontrar alguno de los contextos originales. 

#title: references to "OOCC índice de nombres" entities with no found context
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select distinct ?entity ?oocc_label ?agertokia
where {
  ?entity idp:P32 iwb:Q45164; rdfs:label ?oocc_label. filter(lang(?oocc_label)="eu")
  {?entity ip:P92 ?aipu. ?aipu ipq:P80 ?agertokia. } minus {filter not exists {?entity ip:P92 ?aipu. ?aipu ipq:P93 ?text. }}
  
 } group by ?entity ?oocc_label ?agertokia

Try it!


Entidades mencionadas en OOCC, con denominaciones alternativas

En la primera vuelta, las entidades se han buscado y encontrado en contexto usando la grafía usada en el índice OOCC. Para los que no se pudieron encontrar, se procedió a la definición de nobres alternativos (nombres de artista o grafias alternativas) 

#title: alternative entity labels (for finding them in text)
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select distinct ?entity ?oocc_label (group_concat(str(?alt_label);SEPARATOR=" | ") as ?bilaketarako) 
where { 
  ?entity idp:P32 iwb:Q45164; rdfs:label ?oocc_label. filter(lang(?oocc_label)="eu") 
  ?entity skos:altLabel ?alt_label. filter(lang(?alt_label)="eu") 
 } group by ?entity ?oocc_label ?bilaketarako

Try it!


¿Cuántas entidades aparecen en los textos de OOCC?

#title: OOCC-ko lanetan zenbat izendun entitate *ezberdin* aipatzen diren
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select distinct ?oocc_item ?wikidata ?oocc_itemLabel (count(distinct ?entity) as ?zenbat_entitate)
where {
  ?oocc_item idp:P89 ?oocc_id.
  ?entity idp:P92 ?oocc_item.
  optional {?oocc_item idp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],eu,es". }
 } group by ?oocc_item ?wikidata ?oocc_itemLabel ?zenbat_entitate order by desc(?zenbat_entitate)

Try it!


Entidades de OOCC en Wikidata

Personas en el índice de OOCC encontradas en Wikidata

#title: OOCC-ko izendegiko sarrerak, aipamen-kopuruaren arabera, Wikidatako identifikatzaileekin
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select distinct ?entity ?entityLabel ?wikidata (count(distinct ?oocc_item) as ?zenbat_artikulutan)
where {
  ?oocc_item idp:P89 ?oocc_id.
  ?entity idp:P92 ?oocc_item.
  optional {?entity idp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],eu,es". }
 } group by ?entity ?entityLabel ?wikidata ?zenbat_artikulutan
order by desc(?zenbat_artikulutan)

Try it!

Personas en el índice de OOCC encontradas en Wikidata con algún metadato

#title: Wikipedia-aligned OOCC name index
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select distinct ?entity ?oocc_label ?wikidata ?wikidataLabel ?wikidata_desc ?jaio (sample(?jaiolekuLabel) as ?jaio_leku) ?jarduerak
where {
  ?entity idp:P32 iwb:Q45164; rdfs:label ?oocc_label. filter(lang(?oocc_label)="eu")
  ?entity idp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)
  SERVICE <https://query.wikidata.org/sparql> {
    select ?wikidata ?wikidataLabel ?wikidata_desc ?jaioleku ?jaiolekuLabel ?jaio (group_concat(str(?jarduera); SEPARATOR="; ") as ?jarduerak) where {
      ?wikidata wdt:P31 wd:Q5.
      optional {?wikidata schema:description ?wikidata_desc. filter(lang(?wikidata_desc)="eu")}
      optional {?wikidata wdt:P569 ?jaio.}
      optional {?wikidata wdt:P19 ?jaioleku}
      optional {?wikidata wdt:P106 [rdfs:label ?jarduera]. filter(lang(?jarduera)="eu")}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }  
    } group by ?wikidata ?wikidataLabel ?wikidata_desc ?jaio ?jaioleku ?jaiolekuLabel ?jarduerak
  }
  
 } group by ?entity ?oocc_label ?wikidata ?wikidataLabel ?wikidata_desc ?jaio ?jaio_leku ?jarduerak
order by ?oocc_label

Try it!

Artículos de Wikipedia que describen personas listadas en el índice OOCC

#title: Wikipedia articles about people in OOCC name index
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?entity ?oocc_label (count(distinct ?aipu) as ?zenbat_aipu) ?wikidata ?wikidataLabel ?wikipedia_eu ?wikipedia_es ?wikipedia_en ?wikipedia_fr
where {
  ?entity idp:P32 iwb:Q45164; rdfs:label ?oocc_label. filter(lang(?oocc_label)="eu")
  ?entity idp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)
  ?entity ip:P92 ?aipu.
  SERVICE <https://query.wikidata.org/sparql> {
    select ?wikidata ?wikidataLabel ?wikipedia_eu ?wikipedia_es ?wikipedia_en ?wikipedia_fr where {
      ?wikidata wdt:P31 wd:Q5.
      optional {?wikipedia_eu schema:about ?wikidata. filter(regex(str(?wikipedia_eu), "eu.wikipedia.org"))}
      optional {?wikipedia_es schema:about ?wikidata. filter(regex(str(?wikipedia_es), "es.wikipedia.org"))}
      optional {?wikipedia_en schema:about ?wikidata. filter(regex(str(?wikipedia_en), "en.wikipedia.org"))}
      optional {?wikipedia_fr schema:about ?wikidata. filter(regex(str(?wikipedia_fr), "fr.wikipedia.org"))}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }  
    }}
  
 } group by ?entity ?oocc_label ?zenbat_aipu ?wikidata ?wikidataLabel ?wikipedia_eu ?wikipedia_es ?wikipedia_en ?wikipedia_fr
   order by desc(?zenbat_aipu)

Try it!


Lugares de nacimiento de las personas listadas en el índice de OOCC

#defaultView:Map
#title: Birthplaces of wikidata-aligned people in OOCC izendegi
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?entity ?entityLabel ?wikidata ?label ?jaio_label ?desc ?jaio_data ?jaio_gps ?jpg
where {
  ?entity idp:P32 iwb:Q45164; rdfs:label ?oocc_label. filter(lang(?oocc_label)="eu")
  bind(concat("OOCC izendegian: ",str(?oocc_label)) as ?entityLabel)
  ?entity idp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)
  SERVICE <https://query.wikidata.org/sparql> {
    select ?wikidata ?label ?jaio_label ?jaio_gps ?jaio_data ?desc ?jpg where {
      ?wikidata rdfs:label ?label; wdt:P19 [rdfs:label ?jaio_label; wdt:P625 ?jaio_gps]. filter(lang(?label)="en") filter(lang(?jaio_label)="eu")
      optional {?wikidata wdt:P569 ?jaio_data.}
      optional {?wikidata wdt:P18 ?jpg.}
      optional {?wikidata schema:description ?desc. filter(lang(?desc)="en")}
      }}
  
 } group by ?entity ?entityLabel ?wikidata ?label ?jaio_label ?desc ?jaio_data ?jaio_gps ?jpg

Try it!


Para el ejercicio en Prácticas de Traducción II: personas no descritas en la Wikipedia en castellano

Esta consulta produce una lista de los huecos más siginificativos en la Wikipedia castellana: Las personas del índice de nombres en OOCC que sí que tienen artículo de Wikipedia en euskera, pero no en castellano. 

#title: OOCC name index people with Basque Wikipedia article, but without Spanish Wikipedia article
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?entity (count(distinct ?aipu) as ?zenbat_aipu) ?wikidata ?wikidataLabel ?jaio_leku ?jaio_urte ?wikipedia_eu ?wikipedia_es ?wikipedia_en ?wikipedia_fr
where {
  ?entity idp:P32 iwb:Q45164; rdfs:label ?oocc_label. filter(lang(?oocc_label)="eu")
  ?entity idp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)
  ?entity ip:P92 ?aipu.
  SERVICE <https://query.wikidata.org/sparql> {
    select ?wikidata ?wikidataLabel ?jaio_leku (year(?jaio_data) as ?jaio_urte) ?wikipedia_eu ?wikipedia_es ?wikipedia_en ?wikipedia_fr where {
      ?wikidata wdt:P31 wd:Q5.
      ?wikipedia_eu schema:about ?wikidata. filter(regex(str(?wikipedia_eu), "eu.wikipedia.org"))
      filter not exists {?wikipedia_es schema:about ?wikidata. filter(regex(str(?wikipedia_es), "es.wikipedia.org"))}
      optional {?wikipedia_en schema:about ?wikidata. filter(regex(str(?wikipedia_en), "en.wikipedia.org"))}
      optional {?wikipedia_fr schema:about ?wikidata. filter(regex(str(?wikipedia_fr), "fr.wikipedia.org"))}
      optional {?wikidata wdt:P19 [rdfs:label ?jaio_leku]. filter(lang(?jaio_leku)="eu")}
      optional {?wikidata wdt:P569 ?jaio_data.}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }  
    }}
  
 } group by ?entity ?zenbat_aipu ?wikidata ?wikidataLabel ?jaio_leku ?jaio_urte ?wikipedia_eu ?wikipedia_es ?wikipedia_en ?wikipedia_fr
   order by desc(?zenbat_aipu)

Try it!

Retrieved from "https://wikibase.inguma.eus/w/index.php?title=KM_OOCC_índice_de_nombres&oldid=215726"