KM OOCC izendegi eta hiztegiak

Entitateen agerpenak OOCC-n

2011ko Mitxelenaren Obras Completas (OOCC) argitalpen-sortak izendegi-eranskina dakar („índice de nombres“). Hura eskuz ekoitzi egin zuten argitalpenaren arduradunek. Haien metodoa, itxura denez, Fonética Histórica Vasca liburuak zekarren izendegi eta indizea testu guztietara hedatzea izan zen. Izendegian zerrendatutako entitateak eta agerpen-tokiak Wikibase honetan jaso ditugu. Ondoren, aipu bakoitzari jatorrizko testuingurua gehitzen saiatu gara, alde batetik, eta aipatutako entitatea Wikidatarekin lerrokatzen, bestetik. Izendegiaren erabilgarritasuna hobetzeko ekarpen gisa ulertzen dugu esperimentu hau, Mitxelenaren lana ezagutzeko sarbide berriak irekitzeko proposamen gisa.

OOCC-ko izendegiko entitateen agerpenak testuinguruan 1

Agerpenen testuinguruak baturik agertzen dira (entitate bat, errenkada bat galdeketa honek ekoizten duen taulan)

#title: concepts part of "OOCC índice de nombres", and their occurrences in OOCC
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?entity ?oocc_label ?wikidata (count(distinct ?aipu) as ?zenbat_aipu) (group_concat (distinct ?text; SEPARATOR = "|") as ?contexts)
where {
  ?entity idp:P32 iwb:Q45164; rdfs:label ?oocc_label. filter(lang(?oocc_label)="eu")
  ?entity ip:P92 ?aipu. optional {?aipu ipq:P93 ?text.}
  optional {?entity idp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)}
  
 } group by ?entity ?oocc_label ?wikidata ?zenbat_aipu ?contexts order by desc(?zenbat_aipu)

Try it!

OOCC-ko izendegiko entitateen agerpenak testuinguruan 2

Agerpen bakoitzak bere errenkada du galdeketa honek ekoizten duen taulan.

#title: concepts part of "OOCC índice de nombres" and their occurrences-in-context in OOCC
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select distinct ?entity ?oocc_label ?wikidata ?testua ?testu_izena ?aipua
where {
  ?entity idp:P32 iwb:Q45164; rdfs:label ?oocc_label. filter(lang(?oocc_label)="eu")
  ?entity ip:P92 ?aipu_st. ?aipu_st ips:P92 ?testua. 
  ?testua rdfs:label ?testu_izena. filter(lang(?testu_izena)="eu")
  optional {?aipu_st ipq:P93 ?aipua.} 
  
  optional {?entity idp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)}
  
 } group by ?entity ?oocc_label ?wikidata ?testua ?testu_izena ?aipua order by ?oocc_label ?testua ?aipua

Try it!

OOCC-ko izendegiko entitateen agerpenak (barra-grafikoa)

20 agerpenetik gora duten entitateak, grafiko batean.

#defaultView:BarChart
#title: concepts part of "OOCC índice de nombres", and their occurrences in OOCC
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?entity ?oocc_label ?wikidata ?zenbat_aipu where 
{ filter(?zenbat_aipu >= 20)
 { select ?entity ?oocc_label ?wikidata (count(distinct ?aipu) as ?zenbat_aipu) where 
  { ?entity idp:P32 iwb:Q45164; rdfs:label ?oocc_label. filter(lang(?oocc_label)="eu")
    ?entity ip:P92 ?aipu.
    optional { ?entity idp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata) } 
  } group by ?entity ?oocc_label ?wikidata ?zenbat_aipu 
 } 
} order by desc(?zenbat_aipu)

Try it!

OOCC-ko izendegiko entitateen agerpenak (grafo bisualisazioa)

Datu-multzoa nolabait murrizteko, Wikidatarekin lerrokatutako entitateetara murrizten dugu galdeketa hau.

#defaultView:Graph
#title: concepts part of "OOCC índice de nombres" and their occurrences-in-context in OOCC
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select distinct ?entity ?entityLabel ?testua ?testuaLabel ?rgb
where {
  ?entity idp:P32 iwb:Q45164; idp:P1 ?wd; rdfs:label ?entitylabel. filter(lang(?entitylabel)="eu")
  bind(replace(str(?entitylabel),"\\.[^\\.]*", "") as ?entityLabel) 
  ?entity idp:P92 ?testua. 
  ?testua rdfs:label ?testuaLabel. filter(lang(?testuaLabel)="eu")
  bind ("FFFF99" as ?rgb)
 }

Try it!

OOCC-ko izendegiko entitateak, testuingurua aurkitu ezinekoak

#title: concepts part of "OOCC índice de nombres" with no found context
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select distinct ?entity ?oocc_label ?wikidata
where {
  ?entity idp:P32 iwb:Q45164; rdfs:label ?oocc_label. filter(lang(?oocc_label)="eu")
  filter not exists {?entity ip:P92 ?aipu. ?aipu ipq:P93 ?text. }
  optional {?entity idp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)}
  
 } group by ?entity ?oocc_label ?wikidata ?aipu

Try it!

OOCC-ko lanetan zenbat izendun entitate aipatzen diren

#title: OOCC-ko lanetan zenbat izendun entitate *ezberdin* aipatzen diren
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select distinct ?oocc_item ?wikidata ?oocc_itemLabel (count(distinct ?entity) as ?zenbat_entitate)
where {
  ?oocc_item idp:P89 ?oocc_id.
  ?entity idp:P92 ?oocc_item.
  optional {?oocc_item idp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],eu,es". }
 } group by ?oocc_item ?wikidata ?oocc_itemLabel ?zenbat_entitate order by desc(?zenbat_entitate)

Try it!

OOCC-ko entitateak Wikidatan

OOCC-ko izendegiko wikidatarekin lerrokatutako pertsonak

#title: Wikipedia-aligned OOCC name index
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select distinct ?entity ?oocc_label ?wikidata ?wikidataLabel ?wikidata_desc ?jaio (sample(?jaiolekuLabel) as ?jaio_leku) ?jarduerak
where {
  ?entity idp:P32 iwb:Q45164; rdfs:label ?oocc_label. filter(lang(?oocc_label)="eu")
  ?entity idp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)
  SERVICE <https://query.wikidata.org/sparql> {
    select ?wikidata ?wikidataLabel ?wikidata_desc ?jaioleku ?jaiolekuLabel ?jaio (group_concat(str(?jarduera); SEPARATOR="; ") as ?jarduerak) where {
      ?wikidata wdt:P31 wd:Q5.
      optional {?wikidata schema:description ?wikidata_desc. filter(lang(?wikidata_desc)="eu")}
      optional {?wikidata wdt:P569 ?jaio.}
      optional {?wikidata wdt:P19 ?jaioleku}
      optional {?wikidata wdt:P106 [rdfs:label ?jarduera]. filter(lang(?jarduera)="eu")}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }  
    } group by ?wikidata ?wikidataLabel ?wikidata_desc ?jaio ?jaioleku ?jaiolekuLabel ?jarduerak
  }
  
 } group by ?entity ?oocc_label ?wikidata ?wikidataLabel ?wikidata_desc ?jaio ?jaio_leku ?jarduerak
order by ?oocc_label

Try it!

OOCC-ko izendegiko wikidatarekin lerrokatutako pertsonei buruzko Wikipedia artikuluak

#title: Wikipedia articles about people in OOCC name index
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?entity ?oocc_label (count(distinct ?aipu) as ?zenbat_aipu) ?wikidata ?wikidataLabel ?wikipedia_eu ?wikipedia_es ?wikipedia_en ?wikipedia_fr
where {
  ?entity idp:P32 iwb:Q45164; rdfs:label ?oocc_label. filter(lang(?oocc_label)="eu")
  ?entity idp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)
  ?entity ip:P92 ?aipu.
  SERVICE <https://query.wikidata.org/sparql> {
    select ?wikidata ?wikidataLabel ?wikipedia_eu ?wikipedia_es ?wikipedia_en ?wikipedia_fr where {
      ?wikidata wdt:P31 wd:Q5.
      optional {?wikipedia_eu schema:about ?wikidata. filter(regex(str(?wikipedia_eu), "eu.wikipedia.org"))}
      optional {?wikipedia_es schema:about ?wikidata. filter(regex(str(?wikipedia_es), "es.wikipedia.org"))}
      optional {?wikipedia_en schema:about ?wikidata. filter(regex(str(?wikipedia_en), "en.wikipedia.org"))}
      optional {?wikipedia_fr schema:about ?wikidata. filter(regex(str(?wikipedia_fr), "fr.wikipedia.org"))}
    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],mul,en". }  
    }}
  
 } group by ?entity ?oocc_label ?zenbat_aipu ?wikidata ?wikidataLabel ?wikipedia_eu ?wikipedia_es ?wikipedia_en ?wikipedia_fr
   order by desc(?zenbat_aipu)
 } group by ?entity ?oocc_label ?zenbat_aipu ?wikidata ?wikidataLabel ?wikipedia_eu ?wikipedia_es ?wikipedia_en ?wikipedia_fr
   order by desc(?zenbat_aipu)

Try it!

OOCC-ko izendegiko wikidatarekin lerrokatutako pertsonen jaiolekuak

#defaultView:Map
#title: Birthplaces of wikidata-aligned people in OOCC izendegi
#defaultView:Map
#title: Birthplaces of wikidata-aligned people in OOCC izendegi
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?entity ?entityLabel ?wikidata ?label ?jaio_label ?desc ?jaio_data ?jaio_gps
where {
  ?entity idp:P32 iwb:Q45164; rdfs:label ?oocc_label. filter(lang(?oocc_label)="eu")
  bind(concat("OOCC izendegian: ",str(?oocc_label)) as ?entityLabel)
  ?entity idp:P1 ?wd. bind(iri(concat(str(wd:),?wd)) as ?wikidata)
  SERVICE <https://query.wikidata.org/sparql> {
    select ?wikidata ?label ?jaio_label ?jaio_gps ?jaio_data ?desc where {
      ?wikidata rdfs:label ?label; wdt:P19 [rdfs:label ?jaio_label; wdt:P625 ?jaio_gps]. filter(lang(?label)="en") filter(lang(?jaio_label)="eu")
      optional {?wikidata wdt:P569 ?jaio_data.}
      optional {?wikidata schema:description ?desc. filter(lang(?desc)="en")}
      }}
  
 } group by ?entity ?entityLabel ?wikidata ?label ?jaio_label ?desc ?jaio_data ?jaio_gps

Try it!