Koldo Mitxelena: grafo de citaciones

From Inguma Wikibase

Euskarazko bertsiora joan

Koldo Mitxelena: grafo de citaciones

En esta página describimos los experimentos llevados a cabo relacionados con las citaciones a la obra de Koldo Mitxelena.

Objetivos

  • Recoger la bibliografía completa de Koldo Mitxelena en esta instancia de Wikibase
  • Recoger los artículos de las revistas ASJU y UZTARO en esta Wikibase y identificar aquellos artículos que citan a Mitxelena
  • Recoger las relaciones de citación en esta Wikibase
  • Recoger todos los artículos de Obras Completas con sus metadatos y enlazarlos con las ediciones anteriores
  • Visualizar el grafo de citaciones
  • Incluir todos los datos en Wikidata
  • Recoger metadatos de proceso, para poder predecir la carga de trabajo para confeccionar grafos de citación más grandes

Koldo Mitxelena: bibliografia

Primero recogimos las publicaciones de Koldo Mitxelena, para poder enlazarlos desde los artículos que los citan. Después de fusionar datos de varias fuentes, tenemos 1665 entradas bibliográficas con Koldo Mitxelena como autor.

Las fuentes fueron las siguientes:

Obras Completas (2011, Lakarra & Ruiz ed.)

Producimos los metadatos de publicación para los 737 textos de OOCC. Este trabajo lo realizamos unsando Zotero (véanse OOCC en Zotero).

Bibliografía por Elixabete Pérez Gaztelu

Esta bibliografía fue publicada en papel en el año 1997 (ver entrada en worldcat). Las entradas bibliográficas obtenidas por OCR fueron estructuradas mediante expresiones regulares. La bibliografía tiene 721 entradas, de las cuales 441 tienen a Koldo Mitxelena como autor, mientras que las demás son artículos que citan a éstos. En el futuro, queremos recoger también éstas relaciones.

DialNet

De DialNet (entrada de Koldo Mitxelena) importamos 166 entradas bibliográficas a Zotero.

INGUMA

En esta Wikibase ya tenían representación unas 30 publicaciones (en euskera) de Koldo Mitxelena.

KM Bibliografía

Obras Completas 2011

Para ver las secciones de las OOCC de 2011, usar esta consulta. 

PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?oocc_item ?zotero_link ?oocc_id ?oocc_title (group_concat(?lehen_arg) as ?lehen_argi) ?oocc_text ?jatorrizko_argitalpena 
where {
  ?oocc_item ip:P89 ?oocc_st.
  ?oocc_st ips:P89 ?oocc_id.
  ?oocc_st ipq:P75 ?oocc_text.
  bind(replace(?oocc_text, "(.*)(19[0-9][0-9])(.*)", "$2") as ?lehen_arg)
  ?oocc_item idp:P10 ?oocc_title.
  optional {
    ?oocc_st ipq:P91 ?jatorria.
    bind(iri(concat(str(iwb:),?jatorria)) as ?jatorrizko_argitalpena)
 }
  optional {
    ?oocc_item idp:P71 ?zotero.
    bind(iri(concat("https://www.zotero.org/groups/5597887/ziterauzi/items/",?zotero,"/item-details")) as ?zotero_link)
    }
 }  
group by ?oocc_item ?zotero_link ?oocc_id ?oocc_title ?lehen_argi ?oocc_text ?jatorrizko_argitalpena
order by xsd:integer(?oocc_id)

Try it!

Todas las publiciones de Mitxelena

Esta consulta lista todas las publicaciones, incluyendo reediciones. 

PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?bib_item ?wikidata ?EPG_bib ?oocc (strafter(?dialnet, "articulo?codigo=") as ?Dialnet_id) ?Inguma_id ?worldcat_id
?bib_itemLabel (YEAR(?date) as ?year)
where {
  ?bib_item idp:P17 iwb:Q201; idp:P19 ?date.
  optional {?bib_item idp:P1 ?wikidata.}
  optional {?bib_item idp:P70 ?EPG_bib.}
  optional {?bib_item idp:P89 ?oocc.}
  optional {?bib_item idp:P86 ?dialnet.}
  optional {?bib_item idp:P12 ?Inguma_id.}
  optional {?bib_item idp:P46 ?worldcat_id.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,eu". }
 } group by ?bib_item ?wikidata ?EPG_bib ?oocc ?dialnet ?Inguma_id ?worldcat_id ?bib_itemLabel ?date
order by xsd:integer(?year) lcase(?label)

Try it!

Las publicaciones de Mitxelena a través del tiempo

#defaultView:BarChart
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>

select ?data (count (?bib_item) as ?zenbat_lan)
where {?bib_item idp:P17 iwb:Q201; idp:P19 ?data.}
group by ?data ?zenbat_lan

Try it!

Ediciones previas a OOCC

Este grafo muestra las ediciones previas enlazadas a su versión en OOCC. 

#defaultView:Graph
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>

select ?argitalpen_zahar ?argitalpen_zaharLabel ?rgb ?oocc ?ooccLabel
where {?argitalpen_zahar idp:P88 ?oocc; idp:P19 ?data.
       bind(str(year(?data)) as ?argitalpen_zaharLabel)
       bind("FFFF99" as ?rgb)
       ?oocc idp:P10 ?ooccLabel .
       }

Try it!

Fuentes de los documentos a procesar

Revista ASJU

Se recogieron 423 artículos de ASJU en esta Wikibase, se guardaron los textos completos en PDF, que se procesaron después con la herramienta GROBID, para obtener la versión TEI-XML. Buscando los textos "Mitxelena" y "Michelena" en ellos, se definió un conjunto de 251, donde buscaríamos citas de Mitxelena. De los 251, 175 efectivamente tienen citas a Mitxelena.

Revista UZTARO

808 artículos se descargaron en formato PDF del portal de la revista, y se buscaron los textos "Mitxelena" y "Michelena" kateak bilatu dira, reduciendo así el grupo a procesar a 81 artículos.

Se encontraron citas a Mitxelena en 37 artículos. Por lo demás, en algunos se menciona Mitxelena pero no se cita, o aparece el apellido Mitxelena sin referirse a Koldo Mitxelena.

Flujo de trabajao para identificar las relaciones de cita y enriquecer los metadatos de artículo

Guardamos los metadatos de las publicaciones de Koldo Mitxelena en una Zotero group library: https://www.zotero.org/groups/5597887/ziterauzi/library. Usamos una aplicación que conecta Zotero y Wikibase, para mandar entradas bibliográficas de Zotero a Wikibase.

En esta fase, solamente recogimos citas a las publicaciones de Koldo Mitxelena. También recogimos las entradas de las publicaciones citadas, para poder representar la relación de cita; las recogimos enteras y revisadas usando Zotero (por ejemplo, algunos del portal de la revista RSBAP).

Relaciones de cita

Citas a Mitxelena, enlazadas con OOCC

PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?aipatzen_duena ?aipatzen_duenaLabel (group_concat(?egileaLabel) as ?egileak) (year(?data) as ?urtea) ?oocc_item ?oocc_id ?oocc_title 
where {
  ?oocc_item ip:P89 ?oocc_st.
  ?oocc_st ips:P89 ?oocc_id.
  ?oocc_st ipq:P75 ?oocc_text.
  ?oocc_item idp:P10 ?oocc_title.
  
  ?aipatzen_duena idp:P62 [idp:P88* ?oocc_item].
  
  ?aipatzen_duena idp:P19 ?data; idp:P17 [rdfs:label ?egileaLabel]. filter(lang(?egileaLabel)="eu")
 SERVICE wikibase:label { bd:serviceParam wikibase:language "en,eu". }
}  
group by ?aipatzen_duena ?aipatzen_duenaLabel ?egileak ?data ?oocc_item ?oocc_id ?oocc_title
order by xsd:integer(?oocc_id)

Try it!

Grafo de citación

Citas a Mitxelena, redirigidas a OOCC

#defaultView:Graph
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>

select distinct ?aipu_iturri ?aipu_iturriLabel ?rgb ?edgeLabel ?aipu_xede ?aipu_xedeLabel 
where { ?aipu_xede idp:P89 ?oocc_id. ?aipu_iturri idp:P62 [idp:P88* ?aipu_xede] . # P88: OOCC
       bind("FFFF99" as ?rgb) bind("aipu" as ?edgeLabel)
       SERVICE wikibase:label { bd:serviceParam wikibase:language "eu, es, en, fr". }
      }

Try it!

Citas a Mitxelena, sin redirigir a OOCC

#defaultView:Graph
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>

select ?aipu_iturri ?aipu_iturriLabel ?rgb ?edgeLabel ?aipu_xede ?aipu_xedeLabel 
where { ?aipu_iturri idp:P62 ?aipu_xede . ?aipu_xede idp:P17 iwb:Q201.
       bind("FFFF99" as ?rgb) bind("aipu" as ?edgeLabel)
       SERVICE wikibase:label { bd:serviceParam wikibase:language "eu, es, en, fr". }
      }

Try it!

Publicaciones citadas en un artículo

#defaultView:Graph
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>

select distinct ?aipu_iturri ?aipu_iturriLabel ?rgb ?edgeLabel ?aipu_xede ?aipu_xedeLabel 
where { bind(iwb:Q30912 as ?aipu_iturri)
  ?aipu_xede idp:P89 ?oocc_id. ?aipu_iturri idp:P62 [idp:P88* ?aipu_xede] . # P88: OOCC
       bind("FFFF99" as ?rgb) bind("aipu" as ?edgeLabel)
       SERVICE wikibase:label { bd:serviceParam wikibase:language "eu, es, en, fr". }
      }

Try it!

Publicaciones citadas por un autor

#defaultView:Graph
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>

select distinct ?egile ?egileLabel ?rgb ?edgeLabel ?aipu_xede ?aipu_xedeLabel 
where { bind(iwb:Q9553 as ?egile)
  ?aipu_xede idp:P89 ?oocc_id. ?aipu_iturri idp:P17 ?egile; idp:P62 [idp:P88* ?aipu_xede] . # P88: OOCC
       bind("FFFF99" as ?rgb) bind("aipu" as ?edgeLabel)
       SERVICE wikibase:label { bd:serviceParam wikibase:language "eu, es, en, fr". }
      }

Try it!


¿Cuántas citas tiene cada trabajo de Koldo Mitxelena?

OOCC aurreko argitalpenen aipuak OOCC-ko itemean batuta agertzen dira. 

#defaultView:BubbleChart
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?oocc_item  ?oocc_itemLabel (count(?aipatzen_duena) as ?zenbat_aipu) 
where {
  ?oocc_item ip:P89 ?oocc_st.
  ?oocc_st ips:P89 ?oocc_id.
  ?aipatzen_duena idp:P62 [idp:P88* ?oocc_item].
 SERVICE wikibase:label { bd:serviceParam wikibase:language "en,eu". }
}  
group by ?oocc_item ?oocc_itemLabel ?zenbat_aipu 
order by desc(?zenbat_aipu)

Try it!

Consultas relacionadas a la exportación de datos a Wikidata

Véase la página KM Wikidata export.

Retrieved from "https://wikibase.inguma.eus/w/index.php?title=Koldo_Mitxelena:_grafo_de_citaciones&oldid=215735"