Ziterauzi KM: Difference between revisions

From Inguma Wikibase
 
(One intermediate revision by the same user not shown)
Line 163: Line 163:
       }
       }
</sparql>
</sparql>
==== Artikulu jakin batek aipatzen dituen lanak ====
<sparql tryit="1">
#defaultView:Graph
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
select distinct ?aipu_iturri ?aipu_iturriLabel ?rgb ?edgeLabel ?aipu_xede ?aipu_xedeLabel
where { bind(iwb:Q30912 as ?aipu_iturri)
  ?aipu_xede idp:P89 ?oocc_id. ?aipu_iturri idp:P62 [idp:P88* ?aipu_xede] . # P88: OOCC
      bind("FFFF99" as ?rgb) bind("aipu" as ?edgeLabel)
      SERVICE wikibase:label { bd:serviceParam wikibase:language "eu, es, en, fr". }
      }
</sparql>
==== Autore jakin batek aipatzen dituen lanak ====
<sparql tryit="1">
#defaultView:Graph
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
select distinct ?egile ?egileLabel ?rgb ?edgeLabel ?aipu_xede ?aipu_xedeLabel
where { bind(iwb:Q9553 as ?egile)
  ?aipu_xede idp:P89 ?oocc_id. ?aipu_iturri idp:P17 ?egile; idp:P62 [idp:P88* ?aipu_xede] . # P88: OOCC
      bind("FFFF99" as ?rgb) bind("aipu" as ?edgeLabel)
      SERVICE wikibase:label { bd:serviceParam wikibase:language "eu, es, en, fr". }
      }
</sparql>
=== Zenbat aipu du KM-en lan bakoitzak? ===
=== Zenbat aipu du KM-en lan bakoitzak? ===
OOCC aurreko argitalpenen aipuak OOCC-ko itemean batuta agertzen dira.
OOCC aurreko argitalpenen aipuak OOCC-ko itemean batuta agertzen dira.

Latest revision as of 18:59, 17 November 2024

Koldo Mitxelenaren Zitazio-grafoa

Orrialde honetan Koldo Mitxelenaren zitazio-grafoa eraikitzeko burutzen ditugun esperimentuak deskribatzen ditugu.

Helburuak

  • Koldo Mitxelenaren bibliografia Wikibase honetan osorik deskribatzea
  • ASJU eta UZTARO aldizkarietako artikuluak Wikibase honetan deskribatu ostean, haien artean KM-en lanak aipatzen dituzten artikuluak identifikatzea
  • Artikulu horietatik KM-en lanetara doazen zitazio-erlazioak Wikibase honetan errepresentatzea
  • KMen Obras Completas bildumeko atalen metadatuak jasotzea, eta jatorrizko argitalpenekoekin lotzea.
  • Zitazio-grafoa bistaraztea
  • Datu guztiak Wikidatara bidaltzea
  • Proiektuan zehar, prozesu-metadatuak gordetzea, zitazio-grafo handiagoak eraikitzeko lan-karga iragarri ahal izateko

Koldo Mitxelenaren bibliografia

Koldo Mitxelenaren lanak bildu ditugu lehenengoz, haiek aipatzen dituzten lanetatik loturak ezarri ahal izateko. Iturri ezberdinetako bibliografia-sarrerak batu ostean, 499 item bibliografiko ditugu, non KM egile bezala agertzen baiten.

Ondorengoak izan dira iturriak:

Obras Completas (2011, Lakarra & Ruiz arg.)

Bilduma honetako 737 testuren argitalpen-metadatuak ekoitzi egin ditugu, kapitulu mailan. Lan hori Zoteron egin dugu (hemen OOCC Zoteron).

Elixabete Pérez Gazteluk egindako bibliografia

Paperean argitaratu izan zen bibliografia hau 1997. urtean (ikus worldcat sarrera). OCR bitartez lortutako testutik bibliografia-sarrerak egitaratu ditugu espresio erregularrez eta eskuzko lanaz. Bibliografiak 721 sarrera ditu; horietatik 441 Koldo Mitxelena dute egile (gainontzekoak beste egile batzuek egindakoak dira, eta KM-en lanak aipatu egiten dituzte. Etorkizunean, aipu-erlazio horiek ere kontuan hartu nahi ditugu).

DialNet

DialNet-ek Koldo Mitxelenaren sarreran zerrendatzen dituenak Zotero bitartez eskuratu ditugu. 166 sarrera hartu dugu hortik.

INGUMA

Wikibase honetan jada errepresentazioa zuten itemak aintzat hartu ditugu. Euskarazko 30 liburu eta aldizkari-artikulu dira horiek.

KM Bibliografia

Obras Completas 2011

2011ko OOCC edukiak ikusteko, honakoa abiarazi. 

PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?oocc_item ?zotero_link ?oocc_id ?oocc_title (group_concat(?lehen_arg) as ?lehen_argi) ?oocc_text ?jatorrizko_argitalpena 
where {
  ?oocc_item ip:P89 ?oocc_st.
  ?oocc_st ips:P89 ?oocc_id.
  ?oocc_st ipq:P75 ?oocc_text.
  bind(replace(?oocc_text, "(.*)(19[0-9][0-9])(.*)", "$2") as ?lehen_arg)
  ?oocc_item idp:P10 ?oocc_title.
  optional {
    ?oocc_st ipq:P91 ?jatorria.
    bind(iri(concat(str(iwb:),?jatorria)) as ?jatorrizko_argitalpena)
 }
  optional {
    ?oocc_item idp:P71 ?zotero.
    bind(iri(concat("https://www.zotero.org/groups/5597887/ziterauzi/items/",?zotero,"/item-details")) as ?zotero_link)
    }
 }  
group by ?oocc_item ?zotero_link ?oocc_id ?oocc_title ?lehen_argi ?oocc_text ?jatorrizko_argitalpena
order by xsd:integer(?oocc_id)

Try it!

Mitxelenaren argitalpen guztiak

Item guztiak (berrargitalpenak barne) batera ikusteko, honako galdeketa hau abiarazi. 

PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?bib_item ?wikidata ?EPG_bib ?oocc (strafter(?dialnet, "articulo?codigo=") as ?Dialnet_id) ?Inguma_id ?worldcat_id
?bib_itemLabel (YEAR(?date) as ?year)
where {
  ?bib_item idp:P17 iwb:Q201; idp:P19 ?date.
  optional {?bib_item idp:P1 ?wikidata.}
  optional {?bib_item idp:P70 ?EPG_bib.}
  optional {?bib_item idp:P89 ?oocc.}
  optional {?bib_item idp:P86 ?dialnet.}
  optional {?bib_item idp:P12 ?Inguma_id.}
  optional {?bib_item idp:P46 ?worldcat_id.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,eu". }
 } group by ?bib_item ?wikidata ?EPG_bib ?oocc ?dialnet ?Inguma_id ?worldcat_id ?bib_itemLabel ?date
order by xsd:integer(?year) lcase(?label)

Try it!

Mitxelenaren argitalpenak denboran zehar

#defaultView:BarChart
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>

select ?data (count (?bib_item) as ?zenbat_lan)
where {?bib_item idp:P17 iwb:Q201; idp:P19 ?data.}
group by ?data ?zenbat_lan

Try it!

OOCC-ko argitalpenen aurrekoak

OOCC-ko item bakoitzaren aurreko argitalpenak agertzen dira hemen hari lotuta. 

#defaultView:Graph
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>

select ?argitalpen_zahar ?argitalpen_zaharLabel ?rgb ?oocc ?ooccLabel
where {?argitalpen_zahar idp:P88 ?oocc; idp:P19 ?data.
       bind(str(year(?data)) as ?argitalpen_zaharLabel)
       bind("FFFF99" as ?rgb)
       ?oocc idp:P10 ?ooccLabel .
       }

Try it!

Zitazioak erauzteko dokumentuen iturriak

ASJU Aldizkaria

Wikibase honetara INGUMA-tik inportatu ziren ASJU-ko 423 artikulurentzat PDF testu osoak lortu eta GROBID tresnaz prozesatu ditugu, XML-TEI bertsioak eskuratzeko. "Mitxelena" eta "Michelena" kateak bilatuz, 251 itemeko multzo bat finkatu dugu, non KM-ren lanen aipuak bilatuko ditugun. Koldo Mitxelenaren lanen baten erreferentzia bibliografikoa 251 horietatik 175k dute.

UZTARO Aldizkaria

Aldizkaritik zuzenean deskargatu dira 808 artikulu-pdf. Hauetan programa Python txiki baten bidez "Mitxelena" eta "Michelena" kateak bilatu dira, 81 artikulu eskuratu direlarik. Multzo honetan KM-ren lanen aipuak bilatu ditugu, eskuzko lana:

37 artikulutan aurkitu dira KMren aipuak. Gainontzekoetan Mitxelena aipatu arren ez dute aipu bilbliografikorik egin edo ez ziren Koldo Mitxelena autorearen aipamenak.

Zitazio-erlazioak identifikatzeko eta KM-en lanen metadatuak osatzeko lan-fluxua

Koldo Mitxelenaren lanen metadatuak honako Zotero Group Library honetan gordetzen ditugu: https://www.zotero.org/groups/5597887/ziterauzi/library. Zotero eta Wikibase konektatzen dituen Python flask web-aplikazio bati erabili dugu, argitalpen-metadatuen sortak Zotero-tik Wikibase-ra bidaltzeko.

Fase honetan KM-en lanetara doazen zitazio-erlazioak bakarrik hartzen ditugu aintzat, eta item horiek guztiak jasota ditugu printzipioz. Horregatik, badugu identifikatzailea zitazio-erlazioaezarri ahal izateko, Wikibasekoa, alegia. KM-en lanen batekiko zitazio-erlazioa ezartzen dugunean, lan haren metadatu-sorta errebisatzen dugu, eta, behar izanez gero, sortu egiten dugu Zoteron, adibidez, RSBAP webguneko sarrera batetik, adibidez.

Zitazio-erlazioak

Mitxelenaren lanetako aipuak, OOCC-ko itemei lotuta

PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?aipatzen_duena ?aipatzen_duenaLabel (group_concat(?egileaLabel) as ?egileak) (year(?data) as ?urtea) ?oocc_item ?oocc_id ?oocc_title 
where {
  ?oocc_item ip:P89 ?oocc_st.
  ?oocc_st ips:P89 ?oocc_id.
  ?oocc_st ipq:P75 ?oocc_text.
  ?oocc_item idp:P10 ?oocc_title.
  
  ?aipatzen_duena idp:P62 [idp:P88* ?oocc_item].
  
  ?aipatzen_duena idp:P19 ?data; idp:P17 [rdfs:label ?egileaLabel]. filter(lang(?egileaLabel)="eu")
 SERVICE wikibase:label { bd:serviceParam wikibase:language "en,eu". }
}  
group by ?aipatzen_duena ?aipatzen_duenaLabel ?egileak ?data ?oocc_item ?oocc_id ?oocc_title
order by xsd:integer(?oocc_id)

Try it!

Aipuen grafoa

Aipuak aipuaren xedeari dagokion OOCC-ko itemera "birbidalita"

#defaultView:Graph
#defaultView:Graph
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>

select distinct ?aipu_iturri ?aipu_iturriLabel ?rgb ?edgeLabel ?aipu_xede ?aipu_xedeLabel 
where { ?aipu_xede idp:P89 ?oocc_id. ?aipu_iturri idp:P62 [idp:P88* ?aipu_xede] . # P88: OOCC
       bind("FFFF99" as ?rgb) bind("aipu" as ?edgeLabel)
       SERVICE wikibase:label { bd:serviceParam wikibase:language "eu, es, en, fr". }
      }

Try it!

Aipuak, OOCC-ko itemera birbidali gabe

#defaultView:Graph
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>

select ?aipu_iturri ?aipu_iturriLabel ?rgb ?edgeLabel ?aipu_xede ?aipu_xedeLabel 
where { ?aipu_iturri idp:P62 ?aipu_xede . ?aipu_xede idp:P17 iwb:Q201.
       bind("FFFF99" as ?rgb) bind("aipu" as ?edgeLabel)
       SERVICE wikibase:label { bd:serviceParam wikibase:language "eu, es, en, fr". }
      }

Try it!

Artikulu jakin batek aipatzen dituen lanak

#defaultView:Graph
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>

select distinct ?aipu_iturri ?aipu_iturriLabel ?rgb ?edgeLabel ?aipu_xede ?aipu_xedeLabel 
where { bind(iwb:Q30912 as ?aipu_iturri)
  ?aipu_xede idp:P89 ?oocc_id. ?aipu_iturri idp:P62 [idp:P88* ?aipu_xede] . # P88: OOCC
       bind("FFFF99" as ?rgb) bind("aipu" as ?edgeLabel)
       SERVICE wikibase:label { bd:serviceParam wikibase:language "eu, es, en, fr". }
      }

Try it!

Autore jakin batek aipatzen dituen lanak

#defaultView:Graph
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>

select distinct ?egile ?egileLabel ?rgb ?edgeLabel ?aipu_xede ?aipu_xedeLabel 
where { bind(iwb:Q9553 as ?egile)
  ?aipu_xede idp:P89 ?oocc_id. ?aipu_iturri idp:P17 ?egile; idp:P62 [idp:P88* ?aipu_xede] . # P88: OOCC
       bind("FFFF99" as ?rgb) bind("aipu" as ?edgeLabel)
       SERVICE wikibase:label { bd:serviceParam wikibase:language "eu, es, en, fr". }
      }

Try it!


Zenbat aipu du KM-en lan bakoitzak?

OOCC aurreko argitalpenen aipuak OOCC-ko itemean batuta agertzen dira. 

#defaultView:BubbleChart
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?oocc_item  ?oocc_itemLabel (count(?aipatzen_duena) as ?zenbat_aipu) 
where {
  ?oocc_item ip:P89 ?oocc_st.
  ?oocc_st ips:P89 ?oocc_id.
  ?aipatzen_duena idp:P62 [idp:P88* ?oocc_item].
 SERVICE wikibase:label { bd:serviceParam wikibase:language "en,eu". }
}  
group by ?oocc_item ?oocc_itemLabel ?zenbat_aipu 
order by desc(?zenbat_aipu)

Try it!

Artikuluak eta aipu-erlazioak Wikidatara bidaltzeko SPARQL galdeketak

Ikus KM Wikidata export orrialdea.

Retrieved from "https://wikibase.inguma.eus/w/index.php?title=Ziterauzi_KM&oldid=154518"