Ziterauzi KM: Difference between revisions

From Inguma Wikibase
 
(11 intermediate revisions by the same user not shown)
Line 53: Line 53:


==== Mitxelenaren argitalpen guztiak ====
==== Mitxelenaren argitalpen guztiak ====
Lau iturrion itemak batera ikusteko, honako galdeketa hau abiarazi.
Item guztiak (berrargitalpenak barne) batera ikusteko, honako galdeketa hau abiarazi.
<sparql tryit="1">
<sparql tryit="1">
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
Line 61: Line 61:
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>


select ?bib_item (strafter(str(?bib_item),"https://wikibase.inguma.eus/entity/") as ?qid) ?EPG_bib ?Dialnet_id ?Inguma_id ?worldcat_id
select ?bib_item ?wikidata ?EPG_bib ?oocc (strafter(?dialnet, "articulo?codigo=") as ?Dialnet_id) ?Inguma_id ?worldcat_id
?bib_itemLabel (YEAR(?date) as ?year)
?bib_itemLabel (YEAR(?date) as ?year)
where {
where {
   ?bib_item idp:P17 iwb:Q201; idp:P19 ?date.
   ?bib_item idp:P17 iwb:Q201; idp:P19 ?date.
  optional {?bib_item idp:P1 ?wikidata.}
   optional {?bib_item idp:P70 ?EPG_bib.}
   optional {?bib_item idp:P70 ?EPG_bib.}
   optional {?bib_item idp:P86 ?Dialnet_id.}
  optional {?bib_item idp:P89 ?oocc.}
   optional {?bib_item idp:P86 ?dialnet.}
   optional {?bib_item idp:P12 ?Inguma_id.}
   optional {?bib_item idp:P12 ?Inguma_id.}
   optional {?bib_item idp:P46 ?worldcat_id.}
   optional {?bib_item idp:P46 ?worldcat_id.}
   SERVICE wikibase:label { bd:serviceParam wikibase:language "en,eu". }
   SERVICE wikibase:label { bd:serviceParam wikibase:language "en,eu". }
  } group by ?bib_item ?EPG_bib ?Dialnet_id ?Inguma_id ?worldcat_id ?bib_itemLabel ?date
  } group by ?bib_item ?wikidata ?EPG_bib ?oocc ?dialnet ?Inguma_id ?worldcat_id ?bib_itemLabel ?date
order by xsd:integer(?year) lcase(?label)
order by xsd:integer(?year) lcase(?label)
</sparql>
</sparql>
==== Mitxelenaren argitalpenak denboran zehar ====
==== Mitxelenaren argitalpenak denboran zehar ====
<sparql tryit=1">
<sparql tryit=1">
Line 83: Line 86:
group by ?data ?zenbat_lan
group by ?data ?zenbat_lan
</sparql>
</sparql>
==== Mitxelenaren argitalpen birrargitalpenak ====
==== OOCC-ko argitalpenen aurrekoak ====
OOCC-ko item bakoitzaren aurreko argitalpenak agertzen dira hemen hari lotuta.
OOCC-ko item bakoitzaren aurreko argitalpenak agertzen dira hemen hari lotuta.
<sparql tryit=1">
<sparql tryit=1">
Line 96: Line 99:
       }
       }
</sparql>
</sparql>
== Zitazioak erauzteko dokumentuen iturriak ==
== Zitazioak erauzteko dokumentuen iturriak ==
=== IkerGazte Kongresuak ===
=== IkerGazte Kongresuak ===
Line 132: Line 136:
   ?oocc_item idp:P10 ?oocc_title.
   ?oocc_item idp:P10 ?oocc_title.
    
    
   {?aipatzen_duena idp:P62 [idp:P88 ?oocc_item].} union {?aipatzen_duena idp:P62 ?oocc_item.}
   ?aipatzen_duena idp:P62 [idp:P88* ?oocc_item].
    
    
   ?aipatzen_duena idp:P19 ?data; idp:P17 [rdfs:label ?egileaLabel]. filter(lang(?egileaLabel)="eu")
   ?aipatzen_duena idp:P19 ?data; idp:P17 [rdfs:label ?egileaLabel]. filter(lang(?egileaLabel)="eu")
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,eu". }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,eu". }
}   
}   
group by ?aipatzen_duena ?aipatzen_duenaLabel ?egileak ?data ?jatorrizko_argitalpena ?oocc_item ?oocc_id ?oocc_title
group by ?aipatzen_duena ?aipatzen_duenaLabel ?egileak ?data ?oocc_item ?oocc_id ?oocc_title
order by xsd:integer(?oocc_id)
order by xsd:integer(?oocc_id)
</sparql>
</sparql>


=== Aipuen grafoa ===
=== Aipuen grafoa ===
==== Aipuak aipuaren xedeari dagokion OOCC-ko itemera "birbidalita" ====
<sparql tryit="1">
#defaultView:Graph
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
select ?aipu_iturri ?aipu_iturriLabel ?rgb ?edgeLabel ?aipu_xede ?aipu_xedeLabel
where { ?aipu_xede idp:P89 ?oocc_id. ?aipu_iturri idp:P62 [idp:P88* ?aipu_xede] . # P88: OOCC
      bind("FFFF99" as ?rgb) bind("aipu" as ?edgeLabel)
      SERVICE wikibase:label { bd:serviceParam wikibase:language "en,eu". }
      }
</sparql>
==== Aipuak, OOCC-ko itemera birbidali gabe ====
<sparql tryit="1">
<sparql tryit="1">
#defaultView:Graph
#defaultView:Graph
Line 147: Line 165:
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>


select ?aipu_iturri ?aipu_iturriLabel ?rgb ?aipu_xede ?aipu_xedeLabel  
select ?aipu_iturri ?aipu_iturriLabel ?rgb ?edgeLabel ?aipu_xede ?aipu_xedeLabel  
where { ?aipu_iturri idp:P62 [idp:P88* ?aipu_xede] . # P88: OOCC
where { ?aipu_iturri idp:P62 ?aipu_xede .
       bind("FFFF99" as ?rgb)
       bind("FFFF99" as ?rgb) bind("aipu" as ?edgeLabel)
       SERVICE wikibase:label { bd:serviceParam wikibase:language "en,eu". }
       SERVICE wikibase:label { bd:serviceParam wikibase:language "en,eu". }
       }
       }
Line 155: Line 173:


=== Zenbat aipu du KM-en lan bakoitzak? ===
=== Zenbat aipu du KM-en lan bakoitzak? ===
OOCC aurreko argitalpenen aipuak OOCC-ko itemean batuta agertzen dira.
<sparql tryit="1">
<sparql tryit="1">
#defaultView:BubbleChart
#defaultView:BubbleChart
Line 173: Line 192:
order by desc(?zenbat_aipu)
order by desc(?zenbat_aipu)
</sparql>
</sparql>
== Wikidatara bidaltzeko: SPARQL galdeketak ==
[[KM Wikidata export]]

Latest revision as of 09:56, 30 October 2024

Koldo Mitxelenaren Zitazio-grafoa

Orrialde honetan Koldo Mitxelenaren zitazio-grafoa eraikitzeko burutzen ditugun esperimentuak deskribatzen ditugu.

Helburuak

  • Koldo Mitxelenaren bibliografia Wikibase honetan osorik deskribatzea
  • IkerGazte eta ASJU bildumetan, haietako artikuluak Wikibase honetan osorik deskribatu ostean, KM-en lanak aipatzen dituzten artikuluak identifikatzea
  • Artikulu horietatik KM-en lanetara doazen zitazio-erlazioak Wikibase honetan errepresentatzea
  • Pérez Gazteluren bibliografian agertzen diren zitazio-erlazioak Wikibasean jaso, oraindik jasotzeke ditugun lanak ere Wikibasean errepresentatuz (bibliografia hark KM-en lanen bat aipatzen duten lanen zerrendak ditu).
  • Zitazio-grafoa bistaraztea
  • (Datu guztiak Wikidatara bidaltzea)
  • Proiektuan zehar, prozesu-metadatuak gordetzea, zitazio-grafo handiagoak eraikitzeko lan-karga iragarri ahal izateko

Koldo Mitxelenaren bibliografia

Koldo Mitxelenaren lanak bildu ditugu lehenengoz, haiek aipatzen dituzten lanetatik loturak ezarri ahal izateko. Iturri ezberdinetako bibliografia-sarrerak batu ostean, 499 item bibliografiko ditugu, non KM egile bezala agertzen baiten.

Ondorengoak izan dira iturriak:

Elixabete Pérez Gazteluk egindako bibliografia

Paperean argitaratu izan zen bibliografia hau 1997. urtean (ikus worldcat sarrera). OCR bitartez lortutako testutik bibliografia-sarrerak egitaratu ditugu espresio erregularrez eta eskuzko lanaz. Bibliografiak 721 sarrera ditu; horietatik 441 Koldo Mitxelena dute egile (gainontzekoak beste egile batzuek egindakoak dira, eta KM-en lanak aipatu egiten dituzte).

DialNet

DialNet-ek Koldo Mitxelenaren sarreran zerrendatzen dituenak Zotero bitartez eskuratu ditugu. 166 sarrera hartu dugu hortik.

INGUMA

Wikibase honetan jada errepresentazioa zuten itemak aintzat hartu ditugu. Euskarazko 30 liburu eta aldizkari-artikulu dira horiek.

KM Bibliografia: SPARQL galdeketak

Obras Completas 2011

2011ko OOCC edukiak ikusteko, honakoa abiarazi. 

PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?oocc_item ?zotero_link ?oocc_id ?oocc_title (group_concat(?lehen_arg) as ?lehen_argi) ?oocc_text ?jatorrizko_argitalpena 
where {
  ?oocc_item ip:P89 ?oocc_st.
  ?oocc_st ips:P89 ?oocc_id.
  ?oocc_st ipq:P75 ?oocc_text.
  bind(replace(?oocc_text, "(.*)(19[0-9][0-9])(.*)", "$2") as ?lehen_arg)
  ?oocc_item idp:P10 ?oocc_title.
  optional {
    ?oocc_st ipq:P91 ?jatorria.
    bind(iri(concat(str(iwb:),?jatorria)) as ?jatorrizko_argitalpena)
 }
  optional {
    ?oocc_item idp:P71 ?zotero.
    bind(iri(concat("https://www.zotero.org/groups/5597887/ziterauzi/items/",?zotero,"/item-details")) as ?zotero_link)
    }
 }  
group by ?oocc_item ?zotero_link ?oocc_id ?oocc_title ?lehen_argi ?oocc_text ?jatorrizko_argitalpena
order by xsd:integer(?oocc_id)

Try it!


Mitxelenaren argitalpen guztiak

Item guztiak (berrargitalpenak barne) batera ikusteko, honako galdeketa hau abiarazi. 

PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?bib_item ?wikidata ?EPG_bib ?oocc (strafter(?dialnet, "articulo?codigo=") as ?Dialnet_id) ?Inguma_id ?worldcat_id
?bib_itemLabel (YEAR(?date) as ?year)
where {
  ?bib_item idp:P17 iwb:Q201; idp:P19 ?date.
  optional {?bib_item idp:P1 ?wikidata.}
  optional {?bib_item idp:P70 ?EPG_bib.}
  optional {?bib_item idp:P89 ?oocc.}
  optional {?bib_item idp:P86 ?dialnet.}
  optional {?bib_item idp:P12 ?Inguma_id.}
  optional {?bib_item idp:P46 ?worldcat_id.}
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en,eu". }
 } group by ?bib_item ?wikidata ?EPG_bib ?oocc ?dialnet ?Inguma_id ?worldcat_id ?bib_itemLabel ?date
order by xsd:integer(?year) lcase(?label)

Try it!


Mitxelenaren argitalpenak denboran zehar

#defaultView:BarChart
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>

select ?data (count (?bib_item) as ?zenbat_lan)
where {?bib_item idp:P17 iwb:Q201; idp:P19 ?data.}
group by ?data ?zenbat_lan

Try it!

OOCC-ko argitalpenen aurrekoak

OOCC-ko item bakoitzaren aurreko argitalpenak agertzen dira hemen hari lotuta. 

#defaultView:Graph
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>

select ?argitalpen_zahar ?argitalpen_zaharLabel ?oocc ?ooccLabel
where {?argitalpen_zahar idp:P88 ?oocc; idp:P19 ?data.
       bind(str(year(?data)) as ?argitalpen_zaharLabel)
       ?oocc idp:P10 ?ooccLabel .
       }

Try it!


Zitazioak erauzteko dokumentuen iturriak

IkerGazte Kongresuak

IkerGazte kongresu sortako edizio guztietako testu osoak lortu, Wikibaseko item bibliografiko bakoitzarekin lotu ostean, "Mitxelena" eta "Michelena" kateak bilatu ditugu testu osoetan. 19 artikulu identifikatu ditugu, non KM aipatu egiten den: Q35379, Q35404, Q35478, Q35530, Q35533, Q35650, Q35659, Q35662, Q35664, Q35669, Q35759, Q35773, Q35774, Q35781, Q35783, Q37082, Q37130, Q37221, Q37224

ASJU Aldizkaria

Wikibase honetara INGUMA-tik inportatu ziren ASJU-ko 423 artikulurentzat PDF testu osoak lortu eta GROBID tresnaz prozesatu ditugu, XML-TEI bertsioak eskuratzeko. "Mitxelena" eta "Michelena" kateak bilatuz, 251 itemeko multzo bat finkatu dugu, non KM-ren lanen aipuak bilatuko ditugun:

Pérez Gazteluren bibliografia

Paperezko bibliografia honetan 400 bat item zerrendatzen dira, KM-en lan jakin bati erreferentzia egiten diotenak. Wikibasean jaso gabe daude item horiek oraindik (INGUMA eta ASJUkoak izan ezik).

Zitazio-erlazioak identifikatzeko eta KM-en lanen metadatuak osatzeko lan-fluxua

Koldo Mitxelenaren lanen metadatuak (Pérez Gazteluren bibliografiakoak izan ezik) honako Zotero Group Library honetan gordetzen ditugu (Wikibase honetako entitateekin lotuta daude hango sarrerak): https://www.zotero.org/groups/5597887/ziterauzi/library

Zotero eta Wikibase konektatzen dituen Python flask web-aplikazio bati funtzio batzuk erantsi dizkiogu, ataza honetan laguntzeko:

  • Aplikazioak karpeta bateko TEI-XML fitxategietatik GROBID-ek identifikatutako sarrera bibliografikoak hartzen ditu (<listBibl> elementuaren edukia)
  • Zenbait bilaketa abiarazten ditu, ondorengo plataformetan: Google Books, OpenAlex, Wikidata.
  • Aipatutako argitalpena aurkituz gero, hura deskribatzen duen Wikibase entitate bat sortzen du, jatorrizko plataformako identifikatzailea gordez. Horrela, metadatu-sarrera berria aberas daiteke iturri horretatik.
  • Zitazio-erlazioa datu-basean ezartzen da P62 erabiliz (aipatzen duenetik aipatutakora).

Fase honetan KM-en lanetara doazen zitazio-erlazioak bakarrik hartzen ditugu aintzat, eta item horiek guztiak jasota ditugu printzipioz. Horregatik, badugu identifikatzailea zitazio-erlazioaezarri ahal izateko, Wikibasekoa, alegia. KM-en lanen batekiko zitazio-erlazioa ezartzen dugunean, lan haren metadatu-sorta errebisatzen dugu. Hau da, Pérez Gazteluren bibliografiako lanentzat batez ere, metadatu-sorta egokia sortu egiten dugu. Horretarako, Zotero sarrera bat sortzen dugu. Hemengo irudian, TEI-XML-ean agertzen den aipu bat eta haren Zotero sarrera egin berria erakusten dira. Zotero sarrera, kasu honetan, RSBAP webguneko sarrera batetik sortu da, eta Wikibaseko sarrera aberastuko du, lehenik Pérez Gazteluren erreferentzia gordina besterik izan ez zuena. Horretarako, nahikoa da Wikibaseko sarrera duen URIak Zoteroko sarrerara kopiatzera; gainontzekoa script sorta honek egiten du. Ikus hemen irudi bat: OCR-tik zetorren sarrera aberastu baino lehen vs. Zoterokoarekin batu eta gero.

Zitazio-erlazioak

Mitxelenaren lanetako aipuak, OOCC-ko itemei lotuta

PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?aipatzen_duena ?aipatzen_duenaLabel (group_concat(?egileaLabel) as ?egileak) (year(?data) as ?urtea) ?oocc_item ?oocc_id ?oocc_title 
where {
  ?oocc_item ip:P89 ?oocc_st.
  ?oocc_st ips:P89 ?oocc_id.
  ?oocc_st ipq:P75 ?oocc_text.
  ?oocc_item idp:P10 ?oocc_title.
  
  ?aipatzen_duena idp:P62 [idp:P88* ?oocc_item].
  
  ?aipatzen_duena idp:P19 ?data; idp:P17 [rdfs:label ?egileaLabel]. filter(lang(?egileaLabel)="eu")
 SERVICE wikibase:label { bd:serviceParam wikibase:language "en,eu". }
}  
group by ?aipatzen_duena ?aipatzen_duenaLabel ?egileak ?data ?oocc_item ?oocc_id ?oocc_title
order by xsd:integer(?oocc_id)

Try it!


Aipuen grafoa

Aipuak aipuaren xedeari dagokion OOCC-ko itemera "birbidalita"

#defaultView:Graph
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>

select ?aipu_iturri ?aipu_iturriLabel ?rgb ?edgeLabel ?aipu_xede ?aipu_xedeLabel 
where { ?aipu_xede idp:P89 ?oocc_id. ?aipu_iturri idp:P62 [idp:P88* ?aipu_xede] . # P88: OOCC
       bind("FFFF99" as ?rgb) bind("aipu" as ?edgeLabel)
       SERVICE wikibase:label { bd:serviceParam wikibase:language "en,eu". }
      }

Try it!


Aipuak, OOCC-ko itemera birbidali gabe

#defaultView:Graph
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>

select ?aipu_iturri ?aipu_iturriLabel ?rgb ?edgeLabel ?aipu_xede ?aipu_xedeLabel 
where { ?aipu_iturri idp:P62 ?aipu_xede .
       bind("FFFF99" as ?rgb) bind("aipu" as ?edgeLabel)
       SERVICE wikibase:label { bd:serviceParam wikibase:language "en,eu". }
      }

Try it!


Zenbat aipu du KM-en lan bakoitzak?

OOCC aurreko argitalpenen aipuak OOCC-ko itemean batuta agertzen dira. 

#defaultView:BubbleChart
PREFIX iwb: <https://wikibase.inguma.eus/entity/>
PREFIX idp: <https://wikibase.inguma.eus/prop/direct/>
PREFIX ip: <https://wikibase.inguma.eus/prop/>
PREFIX ips: <https://wikibase.inguma.eus/prop/statement/>
PREFIX ipq: <https://wikibase.inguma.eus/prop/qualifier/>

select ?oocc_item  ?oocc_itemLabel (count(?aipatzen_duena) as ?zenbat_aipu) 
where {
  ?oocc_item ip:P89 ?oocc_st.
  ?oocc_st ips:P89 ?oocc_id.
  ?aipatzen_duena idp:P62 [idp:P88* ?oocc_item].
 SERVICE wikibase:label { bd:serviceParam wikibase:language "en,eu". }
}  
group by ?oocc_item ?oocc_itemLabel ?zenbat_aipu 
order by desc(?zenbat_aipu)

Try it!

Wikidatara bidaltzeko: SPARQL galdeketak

KM Wikidata export

Retrieved from "https://wikibase.inguma.eus/w/index.php?title=Ziterauzi_KM&oldid=150022"